// This file is in Magma syntax. It deals with calculations involving 
// the presentations of various groups. There is a second file in the same
// directory called cs-surface-matrices_magma.txt which deals with matrix calculations.

// Here is the presentation of $\bar\Gamma$ found in [CS2]
// The relations in relnlist below are those listed in Theorem 1.

F<xu,xv,xb>:=FreeGroup(3);
relnlist:={
xu^3,
xv^4,
(xu*xv)^2*(xv*xu)^(-2),
xb^3,
xb*xv*xb^-1*xv^-1,
(xb*xu*xv)^3,
(xb*xu*xv*xu)^2*xv};

G,phi:=quo< F | relnlist>;
u:=phi(xu);
v:=phi(xv);
b:=phi(xb);
j:=(u*v)^2;
ui:=u^-1;
vi:=v^-1;
bi:=b^-1;
ji:=j^-1;

// Setting up a convenient list of elements of $K=\langle u,v\rangle$.
// Here is a transversal in $K$ for the cyclic subgroup generated by $j=(uv)^2$.
// That is, it is a list $t_1,\ldots,t_{24}$ of 24 elements of $K$ so that $K$
// is a union of the 24 cosets $t_a\langle j\rangle$ of the subgroup $\langle j\rangle$ of $K$.
// This list can be found, for example, but setting up the group $K$ as a finitely
// presented group, and using the Transversal(Gp,subgp) command, as follows:
FK<yu,yv>:=FreeGroup(2);
relnlistK:={
yu^3,
yv^4,
(yu*yv)^2*(yv*yu)^(-2)};

Kgp,phiK:=quo< FK | relnlistK>;
uK:=phiK(yu);
vK:=phiK(yv);
jK:=(uK*vK)^2;
uKi:=uK^-1;
vKi:=vK^-1;
jKi:=jK^-1;

print "The order of Kgp is",#Kgp; // Output: 288
ZK:=sub< Kgp | jK>;

// The command 
// Transversal(Kgp,ZK); 
// gives a transversal of $\langle j\rangle$ in $K$.
// The following is a slight edit of the output of that command.

Jtransversal:=[ G |
Id(G),
v,
vi,
u,
ui,
v^2,
v*u,
v*ui,
vi*u,
u*v,
ui*v,
u*vi,
v^2*u,
v^2*ui,
v*u*vi,
v*ui*v,
vi*u*vi,
u*v^2,
u*vi*u,
v^2*u*vi,
vi*u*v^2,
u*v^2*ui,
ui*v^2*u,
v*ui*v^2*u];

// Here is a list of the 288 elements of $K$:

kklist:=[ G | Jtransversal[i1]*j^i2 : i1 in [1 .. 24], i2 in [0 .. 11]];

jtransversalwordlist:=[
[],
["v"],
["vi"],
["u"],
["ui"],
["v","v"],
["v","u"],
["v","ui"],
["vi","u"],
["u","v"],
["ui","v"],
["u","vi"],
["v","v","u"],
["v","v","ui"],
["v","u","vi"],
["v","ui","v"],
["vi","u","vi"],
["u","v","v"],
["u","vi","u"],
["v","v","u","vi"],
["vi","u","v","v"],
["u","v","v","ui"],
["ui","v","v","u"],
["v","ui","v","v","u"]];

jwordlist:=[
[],
["j"],
["j","j"],
["j","j","j"],
["j","j","j","j"],
["j","j","j","j","j"],
["j","j","j","j","j","j"],
["j","j","j","j","j","j","j"],
["j","j","j","j","j","j","j","j"],
["j","j","j","j","j","j","j","j","j"],
["j","j","j","j","j","j","j","j","j","j"],
["j","j","j","j","j","j","j","j","j","j","j"]];

kkwordlist:=[jtransversalwordlist[i1] cat jwordlist[i2] : i1 in [1 .. 24], i2 in [1 .. 12]];

// Calculations for Theorem 2:
// ***************************

// Here are the generators of the index 864 group $\Pi$ given in Theorem 2:

a1:=v*u*vi*j^4*b*u*v*j^2;
a2:=v^2*u*b*u*vi*u*v^2*j;
a3:=ui*v^2*u*j^9*b*vi*u*vi*j^8;

a1i:=a1^-1;
a2i:=a2^-1;
a3i:=a3^-1;

Pi:=sub< G | a1,a2,a3>;

// The following checks that $\Pi$ has abelianization $\Z^2$:
print "AbelianQuotientInvariants(Pi)=",AbelianQuotientInvariants(Pi); // Output: [0,0]

// Checking that $\Pi$ has index 864 in $\bar\Gamma$:

print "Index of Pi in G is",Index(G,Pi); // Output: 864

// Checking that the elements $b^\mu k$, $\mu=-1,0,1$, $k\in K$, form
// a set of coset representatives for the cosets $\Pi g$ of $\Pi$ in $\bar\Gamma$.

Pitransversal:=[ G | b^j1*kklist[j2]: j1 in [-1,0,1], j2 in [1 .. 288]];

// print "Checking that Pitransversal is indeed a transversal for Pi in barGamma";
// print "This takes a few minutes. Progress seems slow at first, but it gets faster.";
// for i1 in [1 .. 864] do
//  if IsDivisibleBy(i1,10) then print "Up to ",i1," out of 864"; end if;
//  for i2 in [i1+1 .. 864] do
//   testgp:=sub< G | a1,a2,a3,Pitransversal[i1]*Pitransversal[i2]^-1>;
//   idx:=Index(G,testgp);
//   if (idx eq 864) then print "Problem: For i1 =",i1,"and i2=",i2,"the index of testgp in G is 864"; end if;
//  end for;
// end for;

// We know that given any element $g$ of $\bar\Gamma$ having order 2 or 3, $g$ or $g^{-1}$ is conjugate to
// one of the elements in the following two lists (see the file cs-surface-matrices_magma.txt and Proposition 1 for details):

order2replist:=[ G | v^2,j^6,(b*ui)^2];
order3replist:=[ G | u,j^4,u*j^4,b*u*v];

// If $\Pi$ had any nontrivial elements of finite order, then it would
// nontrivial elements of order dividing 24, and so elements of order either 2 or 3.
// So it would contain a conjugate of one of the elements in order2replist or order3replist.
// So it would contain a conjugate by $b^\mu k$ of one of these elements.
// We next check that this is not the case:

for t in order2replist do
 for ii in [1 .. 864] do
  testgp:=sub< G | a1,a2,a3,Pitransversal[ii]*t*Pitransversal[ii]^-1>;
  idx:=Index(G,testgp);
  if (idx eq 864) then print "Problem"; end if;
 end for;
end for;
print "Finished checking that Pi contains no elements of order 2.";
for t in order3replist do
 for ii in [1 .. 864] do
  testgp:=sub< G | a1,a2,a3,Pitransversal[ii]*t*Pitransversal[ii]^-1>;
  idx:=Index(G,testgp);
  if (idx eq 864) then print "Problem"; end if;
 end for;
end for;
print "Finished checking that Pi contains no elements of order 3.";
print "Finished checking that Pi is torsion-free.";

// End of calculations for Theorem 2.
// **********************************

// Calculations for the last part of Section 1.5.
// **********************************************

// Checking that the normalizer in $\bar\Gamma$ of $\Pi$ contains $\Pi$
// as a subgroup of index 3, and is generated by $\Pi$ and $j^4$.

NPi:=Normalizer(G,Pi);
print "The index of the normalizer of Pi in barGamma is",Index(G,NPi); // Output: 288
print "It is",j^4 in NPi,"that j^4 is in the normalizer of Pi"; // Output: true

// Checking that we can choose the isomorphism $\Pi/[\Pi,\Pi]\to\Z^2$ as given. 
// One way to do this is to get a presentation for $\Pi$ from the given presentation 
// of $\bar\Gamma$ using Magma's Rewrite routine.
// The following elements $a_i'$ generate a subgroup of $\bar\Gamma$ conjugate to $\Pi$:
// For some reason, Magma gives a much neater output when we apply the Rewrite routine 
// to this conjugated subgroup. But of course any relation satisfied by the $a_i'$ is 
// also satisfied by the $a_i$. and vice versa. 
// So we get a presentation of~$\Pi$ which is not so complicated.

a1d:=v^2*ui*ji*b*v*ui;
a2d:=v*ui*ji^2*b*j^2;
a3d:=vi*j^3*b*u*vi*ji;

// // As matrices (see the cs-surface-matrices_magma.txt file),
// A1D:=V^2*UI*JI*B*V*UI;
// A2D:=V*UI*JI^2*B*J^2;
// A3D:=VI*J^3*B*U*VI*JI;
// // The following are zero:
// A1D - (U*V^2*UI*J^3)*A1*(U*V^2*UI*J^3)^-1;
// A2D - (U*V^2*UI*J^3)*A2*(U*V^2*UI*J^3)^-1;
// A3D - (U*V^2*UI*J^3)*A3*(U*V^2*UI*J^3)^-1;

// Pid:=sub< G | a1d,a2d,a3d >;
// RW,phi:=Rewrite(G,Pid);
// 
// print "phi(RW.1)=",phi(RW.1);
// print "phi(RW.2)=",phi(RW.2);
// print "phi(RW.3)=",phi(RW.3);
// 
// RW;
// Relations of a presentation of $\Pi$:
// a1i*a3i*a1*a2^2*a1i*a2i*a3i^3*a2*a1i^2*a3i^3,
// a2^2*a1i*a2i*a1*a3^3*a1*a2i^3*a3^3*a1*a3*a1,
// a3^3*a1^2*a2*a1i*a2i*a1*a3*a2i^3*a3^3*a1*a2,
// a3i*a1i*a2i^2*a3^3*a1*a2i*a1i*a3i^3*a2^3*a3*a1,
// a2i^3*a3^3*a1*a2*a3i^3*a2^3*a3i*a1i*a2i*a1*a3*a1i,
// a3i*a1i*a3i^3*a2^2*a1i^2*a3i^3*a2*a1*a3*a1i*a2*a1*a2i^2*a1i*a3i,
// a3^3*a1^2*a2*a3i*a1i*a2i^2*a3^3*a1^2*a3^3*a1*a3i*a1i*a2i,
// a2i^3*a3^3*a1^2*a2^2*a1i*a2i*a1*a3i*a1i^2*a3i^3*a2^2*a1*a3*a1i,
// a3*a2i^3*a3^3*a1*a3^3*a1*a3^3*a1^2*a2i*a1i^2*a3i^3*a2^2*a1,
// a1i*a3i^3*a2^3*a1i*a2i*a1i*a3i^3*a2^4*a1*a2i*a1i^2*a3i^3*a1*a2i^2*a3^3*a1*a3i*a1i*a2i,
// a3i^2*a2^4*a1*a2i*a1i^2*a3i^3*a1*a2i*a1i^2*a2*a1*a2i^2*a1i*a3*a1^2*a3*a1i*a2*a1*a2i^2*a1i*a2*a1i*a3i^3*a2*a1i*a3i,
// a2i^3*a3^3*a1*a3*a1^2*a2i*a1i^2*a3i^3*a1i*a3i*a1i*a3i^3*a2^3*a1*a2i*a3^3*a1*a2^2*a1*a3*a1i*a3i^2*a1i*a3,
// a1i*a3i^3*a2^3*a3i*a1i*a2i^3*a3^3*a1*a3^3*a1^2*a2*a3*a2i^3*a3^3*a1*a3*a2i^3*a3^3*a1*a3*a1*a3^3*a1^2*a2,

// In the abelianized group, these relations all reduce to multiples of 3*a1-2*a2+7*a3 = 0

// The 36 elements $k_i$ mentioned at the beginning of Section 2.
// **************************************************************
// They are ordered so that the table in Proposition 7 is neat.

// We claim that the following list of 36 elements $k_i$ of $K$
// forms a set of representatives for the double cosets 
// $\Pi g \bar\Gamma_P$ in $\bar\Gamma$. It has the form
// k_1',k_1'*j^4,k_1'*j^8,k_2',k_2'*j^4,...,k_{12}'*j^8:

PibarGammabarGammaPdoublecosetreplist:=[G |
v,v*j^4,v*j^8,
v^2,v^2*j^4,v^2*j^8,
v*u*vi,v*u*vi*j^4,v*u*vi*j^8,
v*ui*v^2*u,v*ui*v^2*u*j^4,v*ui*v^2*u*j^8,
vi,vi*j^4,vi*j^8,
u*v^2,u*v^2*j^4,u*v^2*j^8,
j,j*j^4,j*j^8,
j^2,j^2*j^4,j^2*j^8,
Id(G),j^4,j^8,
j^3,j^3*j^4,j^3*j^8,
u*v,u*v*j^4,u*v*j^8,
ui*vi,ui*vi*j^4,ui*vi*j^8];

// The following is a list of the 24 elements of $\bar\Gamma_P$.
// Working with matrices (see the file cs-surface-matrices_magma.txt),
// we see that this list is just the subgroup $\langle u,b\rangle$ 
// of $\bar\Gamma$ generated by $u$ and $b$. We indicate in the list
// below why the elements not obviously in this subgroup are indeed there.
Pfixerlist:=[ G |
Id(G),
u,
ui,
b,
b*u,
b*ui,
u*b,
u*b*u,
u*b*ui,
ui*b,
ui*b*u,
ui*b*ui,
v*u*b*j,      // = ui*b^2
v*u*b*u*j,    // = ui*b^2*u
v*u*b*ui*j,   // = ui*b^2*ui
j*b*u*v,      // = b^2*ui
j*b*vi*j,     // = b^2
j*b*vi*u*j,   // = b^2*u
u*j*b*u*v,    // = u*b^2*ui
u*j*b*vi*j,   // = u*b^2
u*j*b*vi*u*j, // = u*b^2*u
b*ui*b,
b*ui*b*u,
b*ui*b*ui];

// The following list of 864 elements of $\bar\Gamma$ forms a
// set of representatives for the cosets $\Pi g$ of $\Pi$ in $\bar\Gamma$:

GammaPbasedPitransversal:=[ G | PibarGammabarGammaPdoublecosetreplist[j1]*Pfixerlist[j2]: j1 in [1 .. 36], j2 in [1 .. 24]];

print "Checking that GammaPbasedPitransversal is indeed a transversal for Pi in barGamma";
print "This takes a few minutes. Progress seems slow at first, but it gets faster.";
for i1 in [1 .. 864] do
 if IsDivisibleBy(i1,10) then print "Up to ",i1," out of ",864; end if;
 for i2 in [i1+1 .. 864] do
  testgp:=sub< G | a1,a2,a3,GammaPbasedPitransversal[i1]*GammaPbasedPitransversal[i2]^-1>;
  idx:=Index(G,testgp);
  if (idx eq 864) then print "Problem: For i1 =",i1,"and i2=",i2,"the index of testgp in G is 864"; end if;
 end for;
end for;

// Calculations for Section 2.1.
// *****************************

// The presentation of $\bar\Gamma_0$ given in Section 2.1
// *******************************************************
F0<xs2,xs3,xs12,xz0>:=FreeGroup(4);
relnlist0:={
xs2^2*xz0,
xs3^3,
xs12^12,
xz0^4,
xs12*xs3*xs2,
xs2*xz0*xs2^-1*xz0^-1,
xs3*xz0*xs3^-1*xz0^-1,
xs12*xz0*xs12^-1*xz0^-1
};

Gamma0,phi0:=quo< F0 | relnlist0>;
s2:=phi0(xs2);
s3:=phi0(xs3);
s12:=phi0(xs12);
z0:=phi0(xz0);

// The presentation of $\bar\Gamma_c$ given in Section 2.1
// *******************************************************
Fc<xt2,xt4,xt12,xzc>:=FreeGroup(4);
relnlistc:={
xt2^2,
xt4^4*xzc^-1,
xt12^12,
xzc^3,
xt12*xt4*xt2,
xt2*xzc*xt2^-1*xzc^-1,
xt4*xzc*xt4^-1*xzc^-1,
xt12*xzc*xt12^-1*xzc^-1
};

Gammac,phic:=quo< Fc | relnlistc>;
t2:=phic(xt2);
t4:=phic(xt4);
t12:=phic(xt12);
zc:=phic(xzc);

// End of calculations of Section 2.1.
// ***********************************

// Calculations for Section 2.2.
// *****************************
// There are no Magma calculations in this section.

// End of calculations for Section 2.2.
// ************************************

// Calculations for Proposition 2.
// *******************************

// See the file cs-surface-matrices_magma.txt for verification that the 
// 8 elements $g_1,\ldots,g_8$ of~$\Pi$ given in Proposition 2
// are indeed words in the generators $s_2$, $s_3$, $s_{12}$ and $z_0$
// of $\bar\Gamma_0$ given in Section 2.1.

// Next we check that $g_1,\ldots,g_8$ generate a subgroup
// of $\bar\Gamma_0$ of index 288, and so generate all of $\Pi_0$.
// We use the words for $g_1,\ldots,g_8$ in terms of 
// $s_2$, $s_3$, $s_{12}$ and $z_0$.

// Anticipating this result, we name the following subgroup Pi0:

Pi0:=sub< Gamma0 | 
s12^4*s2*s12^4*s2*s12^4*z0,
s12^8*s2*s12^4*s2*z0,
s12^11*s2*s12^4*s2*s12^9*z0,
s12^3*s2*s12^4*s2*s12^5*z0,
s12^6*s2*s12^4*s2*s12^2*z0,
s12^10*s2*s12^4*s2*s12^10*z0,
s12*s2*s12^4*s2*s12^7*z0,
s12^5*s2*s12^4*s2*s12^3*z0>;

// The following checks that $\Pi_0$ is generated by the given 8 elements of $\bar\Gamma_0$:
print "The index of Pi0 in barGamma_0 is", Index(Gamma0,Pi0); // Output: 288

// We now get a presentation for $\Pi_0$ from that of $\bar\Gamma_0$ 
// by using Magma's Rewrite routine.

// R,f:=Rewrite(Gamma0,Pi0);
// R;
// "f(g1):=",f(Pi0.1);
// "f(g2):=",f(Pi0.2);
// "f(g3):=",f(Pi0.3);
// "f(g4):=",f(Pi0.4);
// "f(g5):=",f(Pi0.5);
// "f(g6):=",f(Pi0.6);
// "f(g7):=",f(Pi0.7);
// "f(g8):=",f(Pi0.8);
// // This gives a presentation of $\Pi_0$ in terms of
// // new generators called R.1,...,R.8.  We change these
// // to R1,...,R8 by editing the output, getting the following
// // cleaned-up output:
// 
// // Finitely presented group R on 8 generators.
// // Generators as words in group Gamma0:
// // R1=s2*s3*s12*s2^-1*s3*s12^2*s3^-1*s12
// // R2=s2*s12^-3*s3*s12^4
// // R3=s12^4*s2*s12^-3*s3
// // R4=s3^-1*s12*s2*s3*s12^2*s3^-1*s12^2
// // R5=s3^-1*s12^4*s2*s12^-3*s3^-1
// // R6=s12^-1*s3*s12^2*s2*s3^-1*s12*s2^-1*s12^-2
// // R7=s12^-2*s3*s12*s2*s3^-1*s12^2*s2^-1*s12^-1
// // R8=s3*s12^-2*s3*s12^4*s2*s12^-1*s3^-1
// // Relations
// // R7^-1*R2^-1*R5*R1^-1*R2*R3*R4*R7*R1*R8^-1*R5^-1*R3^-1*R6^-1*R4^-1*R8*R6=Id(R)
// 
// // Notice that there is only one relation.
// 
// // The map $f$ constructed by the routine gives an isomorphism
// // from $\Pi_0$, with its old generators, to the "rewritten group" $R$:
// f(g1):=R3*R2;
// f(g2):=R2^-1;
// f(g3):=R5^-1*R3^-1;
// f(g4):=R3*R5*R8*R1^-1*R7^-1*R4^-1*R3^-1;
// f(g5):=R3*R4*R7*R1;
// f(g6):=R6;
// f(g7):=R7^-1*R4^-1*R3^-1;
// f(g8):=R3*R4;
// 
// // We solve these equations, getting $R_1,\ldots,R_8$ in terms of the original
// // generators $g_1,\ldots,g_8$.
// R1:=g7*g5;
// R2:=g2I;
// R3:=g1*g2;
// R4:=g2I*g1I*g8;
// R5:=g2I*g1I*g3I;
// R6:=g6;
// R7:=g8I*g7I;
// R8:=g3*g4*g5;
// 
// // We then substitute these expressions into the single relation
// // R7^-1*R2^-1*R5*R1^-1*R2*R3*R4*R7*R1*R8^-1*R5^-1*R3^-1*R6^-1*R4^-1*R8*R6;
// // and cancel any $gi*giI$'s and $giI*gi$'s.
// // The relation becomes
// // g7*g8*g1I*g3I*g5I*g7I*g2I*g4I*g6I*g8I*g1*g2*g3*g4*g5*g6 = Id
// // and conjugating this, we get the relation given in Proposition 2. 

// See the file cs-surface-matrices_magma.txt for the conversion of the $g_i$'s
// to generators $u_i$ and $v_i$ satisfying the standard surface relation.

// End of calculations for Proposition 2.
// **************************************

// Calculations for Proposition 3.
// *******************************
// For Proposition 3(a), we use the fact, checked above in
// the proof of Theorem 2, that the elements $b^\mu k$, $\mu\in\{0,1,-1\}$, $k\in K$,
// form a transversal for $\Pi$ in $\bar\Gamma$.
// For Proposition 3(b), no Magma calculations are necessary.

// For Proposition 3(c), we first check that $g\Pi_0g^{-1}\subset\Pi$ for all
// $g\in\bar\Gamma$. We need only check that $gg_jg^{-1}\in\Pi$ for each of
// the 8 generators $g_1,\ldots,g_8$ of~$\Pi_0$ for each $g$ of the form $b^\mu k$.
// Here are the 8 generators $g_1,\ldots,g_8$ of~$\Pi_0$:
g1:=a3i*a3i*a3i*a1i*a2*a1;
g3:=a2*a1i*a1i*a3i*a3i*a3i*a1i;
g5:=j^4*a2*a1*j^8*a2i*a3*a3*a3*a1*a1;
g7:=j^4*a1i*a2i*j^4*a2*a1*j^4;
g2:=j^4*g1*j^8;
g4:=j^4*g3*j^8;
g6:=j^4*g5*j^8;
g8:=j^4*g7*j^8;

glist:=[ G | g1,g2,g3,g4,g5,g6,g7,g8];

print "Checking that for all mu in {0,1,-1}, k in K";
print "and pi in Pi_0, b^mu*k*pi*k^-1*b^(-mu) is in Pi.";
for jj in [1 .. 8] do
 for ii in [1 .. #kklist] do
  for mu in [0,1,-1] do
   testgp:=sub< G | a1,a2,a3,b^mu*kklist[ii]*glist[jj]*kklist[ii]^-1*b^(-mu)>;
   idx:=Index(G,testgp);
   if (idx lt 864) then print "b^",mu,"*",kkwordlist[ii],"g_",jj,"(",kkwordlist[ii],")^-1*b^(",-mu,") is not in Pi"; end if;
  end for;
 end for;
end for;

// To show that $k_\alpha\Pi_0k_\alpha^{-1}=\Pi_\alpha$ for $\alpha=1,\infty$, we first set up a
// transversal for $\Pi_0$ in $\bar\Gamma_0$ using representatives for the double cosets
// $\Pi_0\gamma K_0$, where $K_0=K\cap\bar\Gamma_0$.

// Here is a list of the elements of $K_0$:
K0list:=[ G | v^i1*j^i2 : i1 in [0 .. 3], i2 in [0 .. 11]];

// We claim that $\bar\Gamma_0$ is the union of the six double cosets $\Pi_0 g K_0$,
// for the elements $g$ in the following list:

Pi0K0doublecosetreplist:=[G | Id(G),j^9*b*j^7,j^10*b*j^7,j^11*b*j^7,b*j^7,j^9*b*j^2*bi*j];

Pi0inbarGamma0transversal:=[ G | Pi0K0doublecosetreplist[i1]*K0list[i2] : i1 in [1 .. 6], i2 in [1 .. 48]];

print "Checking that pizero_in_gammazero_transversal is indeed a transversal for Pi_0 in barGamma_0";
print "by checking that the elements are in different cosets of Pi.";
for i1 in [1 .. 288] do
 if IsDivisibleBy(i1,10) then print "Up to ",i1," out of 288"; end if;
 for i2 in [i1+1 .. 288] do
  testgp:=sub< G | a1,a2,a3,Pi0inbarGamma0transversal[i1]*Pi0inbarGamma0transversal[i2]^-1>;
  idx:=Index(G,testgp);
  if (idx eq 864) then print "Problem: For i1 =",i1,"and i2=",i2,"the index of testgp in G is 864"; end if;
 end for;
end for;

// Here are the 6 elements $k_\alpha$, $\alpha\in\{0,1,-1,i,-i,\infty\}$ given in Lemma 2:
kzero:=Id(G);
kinfty:=ui*v^2*u*j^6;
kplusi:=u*j;
kminus1:=v*u*j;
kminusi:=v^2*u*j;
kplus1:=v^3*u*j;

print "Checking that if t is in Pi0inbarGamma0transversal, and t is not 1";
print "then kplus1*t*kplus1^-1 is not in Pi";
for i1 in [1 .. 288] do
 testgp:=sub< G | a1,a2,a3,kplus1*Pi0inbarGamma0transversal[i1]*kplus1^-1>;
 idx:=Index(G,testgp);
 if (idx eq 864) then print "For i1 =",i1,", kplus1*t_i1*kplus1^-1 is in Pi"; end if;
end for;

print "Checking that if t is in Pi0inbarGamma0transversal, and t is not 1";
print "then kinfty*t*kinfty^-1 is not in Pi";
for i1 in [1 .. 288] do
 testgp:=sub< G | a1,a2,a3,kinfty*Pi0inbarGamma0transversal[i1]*kinfty^-1>;
 idx:=Index(G,testgp);
 if (idx eq 864) then print "For i1 =",i1,", kinfty*t_i1*kinfty^-1 is in Pi"; end if;
end for;

// No Magma calculations are needed for Proposition 3(d).

// End of calculations for Proposition 3.
// **************************************

// Calculations for Proposition 4:
// *******************************

// See the file cs-surface-matrices_magma.txt for the expressing the 20
// generators given for $\Pi_c$ in terms of the generators $t_2$, $t_4$,
// $t_{12}$ and $z_c$ of $\bar\Gamma_c$.
// We first check that they generate a subgroup of index 324 in $\bar\Gamma_c$
// and so generate all of $\Pi_c$. Anticipating this result,
// we call the following subgroup Pic:

Pic:=sub< Gammac | 
t12^6*t2*t12^4*t2*t12^2,
t12^10*t2*t12^4*t2*t12^10,
t12^8*t2*t12^4*t2,
t2*t12^4*t2*t12^8,
t12^5*t2*t12^4*t2*t12^3,
t12^9*t2*t12^4*t2*t12^11,
t12^11*t2*t12^4*t2*t12^9,
t12^3*t2*t12^4*t2*t12^5,
t12^5*t2*t12^10*t2*t12^10*t2*t12^5,
t12^9*t2*t12^10*t2*t12^10*t2*t12,
t12*t2*t12^10*t2*t12^10*t2*t12^9,
t12^6*t2*t12^10*t2*t12^10*t2*t12^4,
t12^10*t2*t12^10*t2*t12^10*t2,
t12^2*t2*t12^10*t2*t12^10*t2*t12^8,
t12^8*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^11*zc^2,
t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^7*zc^2,
t12^5*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^2*zc^2,
t12^9*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^10*zc^2,
t12^6*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12*zc^2,
t12^10*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^9*zc^2>;

// The following checks that $\Pi_c$ is generated by the given 20 elements of $\bar\Gamma_c$:
print "The index of Pic is", Index(Gammac,Pic); // Output: 324

// Now we show that $\Pi_c$ has a presentation with just 
// one relation, as given in the proof of Proposition 4.
// We use Magma's routine Rewrite. This gives a presentation in terms of 
// new generators, which we call R1,... R20.
// R,f:=Rewrite(Gammac,Pic);
// 
// R;
// "f(Gc1)=",f(R.1);
// "f(Gc2)=",f(R.2);
// "f(Gc3)=",f(R.3);
// "f(Gc4)=",f(R.4);
// "f(Gc5)=",f(R.5);
// "f(Gc6)=",f(R.6);
// "f(Gc7)=",f(R.7);
// "f(Gc8)=",f(R.8);
// "f(Gc9)=",f(R.9);
// "f(Gc10)=",f(R.10);
// "f(Gc11)=",f(R.11);
// "f(Gc12)=",f(R.12);
// "f(Gc13)=",f(R.13);
// "f(Gc14)=",f(R.14);
// "f(Gc15)=",f(R.15);
// "f(Gc16)=",f(R.16);
// "f(Gc17)=",f(R.17);
// "f(Gc18)=",f(R.18);
// "f(Gc19)=",f(R.19);
// "f(Gc20)=",f(R.20);
// 
// // The new generators are expressed in terms of
// // the generators t2,t4,t12 and zc of the ambient group Gammac:

// R1=(t12*t4^-1)^3
// R2=(t4*t12*t4^-2)^3
// R3=t12^2*t4^-1*t2*t4^-2*t12*t2
// R4=t2*t4*t12*t2*t4*t12*t2*t12^-1*t4^-1
// R5=t2*t12^-3*t4*t12^4
// R6=t4*t12^2*t4^-1*t2*t4^-2*t12^2
// R7=t12*t2*t4*t12*t2*t12^-1*t4^-1*t2*t4
// R8=t12^4*t2*t12^-3*t4
// R9=t12^3*t4^-1*t2*t4^-2*t12*t2*t12^-1
// R10=t4^-1*t12^2*t4^-1*t2*t4^-2*t12*t2*t4
// R11=t12^-1*t4*t12*t2*t4*t12*t2*t12^-1*t4^-2
// R12=t12^-1*t4*t12^2*t2*t4^-1*t12*t2*t12^-2
// R13=t12^-2*t4*t12*t2*t4^-1*t12^2*t2*t12^-1
// R14=t2*t4*t12^2*t2*t4*zc*t12^-3*t4^-1
// R15=t2*zc*t12^-2*t4^2*t12^2*t2*t12^-1*t4^-1
// R16=t2*t12^-2*t4*t12*t2*t4^-1*t12^2*t2*t4
// R17=t4^2*t12^2*t2*t4*zc*t12*t2*t12^-2
// R18=t4*t12^-1*t4*t12*t2*t4*t12*t2*t12^-1*t4*zc^-1
// R19=t4*t12^-1*t4*t12^2*t2*t12^-5
// R20=t12^4*t4^-1*t2*t12^-3*t4^2
// 
// // and Rewrite tells us that $\Pi_c$ has a presentation with respect
// // to these new generators which has just one relation:
// R6^-1*R4^-1*R3^-1*R7*R10^-1*R18^-1*R14^-1*R4*R15^-1*R16*R20^-1*R9*R13^-1*R5^-1*R8^-1*R20*R17*R12^-1*R11*R1^-1*R14*R6*R13*R1*R19*R8*R10*R16^-1*R5*R19^-1*R18*R2^-1*R12*R3*R15*R2*R7^-1*R9^-1*R17^-1*R11^-1=Id(R)
// // The lines 
// "f(Gci)=",f(R.i);
// // express the old generators Gci in terms of the Ri's. We get
// Gc1=R19I*R18*R2I
// Gc2=R12
// Gc3=R5I
// Gc4=R8I
// Gc5=R19I*R1I*R13I
// Gc6=R13
// Gc7=R14I*R4*R15I*R16*R20I
// Gc8=R9*R13I*R5I*R8I*R20*R17*R12I*R11*R1I*R14*R6*R13*R1*R19*R8*R10*R16I*R5
// Gc9=R19I*R14I*R4*R15I*R16*R20I*R9*R13I*R5I*R8I*R20*R17*R12I*R11*R1I*R14*R6*R13*R1*R19*R8*R10*R16I*R5
// Gc10=R6I
// Gc11=R9I
// Gc12=R19I*R18*R2I*R12*R3*R5
// Gc13=R2
// Gc14=R17I*R20I
// Gc15=R5I*R8I*R20*R17*R12I*R11*R1I
// Gc16=R14*R6*R13*R1*R19
// Gc17=R19I*R14I*R4*R15I*R16*R20I*R9*R13I*R5I*R8I*R20*R17*R12I*R11*R1I*R14*R6*R13*R1*R19*R8*R10*R16I*R5*R19I*R18*R2I*R12*R3*R15*R2*R7I*R9I*R17I*R11I
// Gc18=R6I*R4I*R3I
// Gc19=R19I*R18*R2I*R12*R3*R15
// Gc20=R2*R7I*R9I
// We can solve these equations for the Ri's in terms of the Gci's, getting
// R1 = Gc6I*Gc5I*Gc9*Gc8I*Gc7I;
// R2 = Gc13;
// R3 = Gc2I*Gc1I*Gc12*Gc3;
// R4 = Gc3I*Gc12I*Gc1*Gc2*Gc18I*Gc10;
// R5 = Gc3I;
// R6 = Gc10I;
// R7 = Gc11*Gc20I*Gc13;
// R8 = Gc4I;
// R9 = Gc11I;
// R10 = Gc4*Gc16I*Gc15I*Gc6*Gc11*Gc8*Gc12I*Gc19*Gc10I*Gc18*Gc2I*Gc1I*Gc12*Gc3*Gc16*Gc5*Gc10*Gc7*Gc14I*Gc20I*Gc19I*Gc9I*Gc17*Gc2*Gc14*Gc4I*Gc3I*Gc15*Gc6I*Gc5I*Gc9*Gc8I*Gc7I;
// R11 = Gc2*Gc14*Gc4I*Gc3I*Gc15*Gc6I*Gc5I*Gc9*Gc8I*Gc7I;
// R12 = Gc2;
// R13 = Gc6;
// R14 = Gc16*Gc5*Gc10;
// R15 = Gc3I*Gc12I*Gc19;
// R16 = Gc3I*Gc12I*Gc19*Gc10I*Gc18*Gc2I*Gc1I*Gc12*Gc3*Gc16*Gc5*Gc10*Gc7*Gc14I*Gc20I*Gc19I*Gc9I*Gc17*Gc2*Gc14*Gc4I*Gc3I*Gc15*Gc6I*Gc5I*Gc9*Gc8I*Gc7I;
// R17 = Gc7*Gc8*Gc9I*Gc5*Gc6*Gc15I*Gc3*Gc4*Gc14I*Gc2I*Gc17I*Gc9*Gc19*Gc20;
// R18 = Gc7*Gc8*Gc9I*Gc1*Gc13;
// R19 = Gc7*Gc8*Gc9I;
// R20 = Gc14I*Gc20I*Gc19I*Gc9I*Gc17*Gc2*Gc14*Gc4I*Gc3I*Gc15*Gc6I*Gc5I*Gc9*Gc8I*Gc7I;
// // and we also express the inverses of the Ri's in terms of the Gci's:
// R1I = Gc7*Gc8*Gc9I*Gc5*Gc6;
// R2I = Gc13I;
// R3I = Gc3I*Gc12I*Gc1*Gc2;
// R4I = Gc10I*Gc18*Gc2I*Gc1I*Gc12*Gc3;
// R5I = Gc3;
// R6I = Gc10;
// R7I = Gc13I*Gc20*Gc11I;
// R8I = Gc4;
// R9I = Gc11;
// R10I = Gc7*Gc8*Gc9I*Gc5*Gc6*Gc15I*Gc3*Gc4*Gc14I*Gc2I*Gc17I*Gc9*Gc19*Gc20*Gc14*Gc7I*Gc10I*Gc5I*Gc16I*Gc3I*Gc12I*Gc1*Gc2*Gc18I*Gc10*Gc19I*Gc12*Gc8I*Gc11I*Gc6I*Gc15*Gc16*Gc4I;
// R11I = Gc7*Gc8*Gc9I*Gc5*Gc6*Gc15I*Gc3*Gc4*Gc14I*Gc2I;
// R12I = Gc2I;
// R13I = Gc6I;
// R14I = Gc10I*Gc5I*Gc16I;
// R15I = Gc19I*Gc12*Gc3;
// R16I = Gc7*Gc8*Gc9I*Gc5*Gc6*Gc15I*Gc3*Gc4*Gc14I*Gc2I*Gc17I*Gc9*Gc19*Gc20*Gc14*Gc7I*Gc10I*Gc5I*Gc16I*Gc3I*Gc12I*Gc1*Gc2*Gc18I*Gc10*Gc19I*Gc12*Gc3;
// R17I = Gc20I*Gc19I*Gc9I*Gc17*Gc2*Gc14*Gc4I*Gc3I*Gc15*Gc6I*Gc5I*Gc9*Gc8I*Gc7I;
// R18I = Gc13I*Gc1I*Gc9*Gc8I*Gc7I;
// R19I = Gc9*Gc8I*Gc7I;
// R20I = Gc7*Gc8*Gc9I*Gc5*Gc6*Gc15I*Gc3*Gc4*Gc14I*Gc2I*Gc17I*Gc9*Gc19*Gc20*Gc14;
// 
// // Substituting these into the above relation in the Ri's, we get a single relation
// // in terms of the Gci's. Cancelling any Gci*GciI's and GciI*Gci's, we get the single
// // relation given in the proof of Proposition 4, after a conjugation:
// // The following is the identity:
// Gc4*Gc14I*Gc2I*Gc17I*Gc9*Gc19*Gc20*Gc14*Gc7I*Gc10I*Gc5I*Gc16I*Gc3I*Gc12I*Gc1*Gc2*Gc18I*Gc10*Gc19I*Gc12
// *Gc8I*Gc11I*Gc6I*Gc15*Gc16*Gc4I*Gc13I*Gc1I*Gc17*Gc18*Gc11*Gc20I*Gc13*Gc7*Gc8*Gc9I*Gc5*Gc6*Gc15I*Gc3;

// End of calculations for Proposition 4.
// **************************************

// Calculations for Proposition 5:
// *******************************

// For Proposition 5(a): See the file cs-surface-matrices_magma.txt for the routine
// which finds elements $\pi$ such that $\pi(M)=M'$. No Magma calculations are
// needed for Proposition 5(b).

// For Proposition 5(c), we first set up transversal for $\Pi_c$ in~$\bar\Gamma_c$
// which uses the subgroup $K_c=K\cap\bar\Gamma_c$.
// Here is a list of the elements of $K_c$:
Kclist:=[ G | u^i1*j^i2 : i1 in [0 .. 2], i2 in [0 .. 11]];

// We now show that the following list of 9 elements is a set of double coset
// representatives for $\Pi_c\backslash(\bar\Gamma_c)/K_c$:
PicKcdoublecosetreplist:=[G | Id(G),j^7*b*ui*b*u*j^7,j^8*b*ui*b*u*j^7,j^9*b*ui*b*u*j^7,j^10*b*ui*b*u*j^7,j^7*b*ui*b*u*j^11*b*ui*b*ui*j^2,
j^8*b*ui*b*u*j^11*b*ui*b*ui*j^2,j^9*b*ui*b*u*j^11*b*ui*b*ui*j^2,j^10*b*ui*b*u*j^11*b*ui*b*ui*j^2];

PicinGammactransversal:=[ G | PicKcdoublecosetreplist[i1]*Kclist[i2] : i1 in [1 .. 9], i2 in [1 .. 36]];

print "Checking that Pic_in_Gammac_transversal is indeed a transversal for Pi_c in barGamma_c";
print "by checking that the elements are in different cosets of Pi.";
for i1 in [1 .. 324] do
 if IsDivisibleBy(i1,10) then print "Up to ",i1," out of 324"; end if;
 for i2 in [i1+1 .. 324] do
  testgp:=sub< G | a1,a2,a3,PicinGammactransversal[i1]*PicinGammactransversal[i2]^-1>;
  idx:=Index(G,testgp);
  if (idx eq 864) then print "Problem: For i1 =",i1,"and i2=",i2,"the index of testgp in G is 864"; end if;
 end for;
end for;

// Here are the 20 generators of $\Pi_c$ given in the proof of Proposition 4:
gc1:=j^8*a1i*a2*a1*a3*a1i*j^4*a2*a1;
gc3:=j^4*a2*a1*a2i*a2i*a1i*a3*j^4*a3*a3*a3*j^4;
gc5:=j^8*a1i*j^4*a2*a1*j^4*a3*a2i*a1*a3*a1i*j^8;
gc7:=j^8*a2*a1*j^4*a3i*j^4*a2*a1i*a2i*a3i*a3i*a3i*j^8;
gc9:=j^8*a1i*a2i*a2i*a1i*a3i*j^8*a1i*a2i*j^8;
gc12:=a2i*a1*a3*a1i*a3i*j^4*a3*a1*a2*a2*a1i*a2i*j^8;
gc15:=j^4*a1*j^4*a2*a3*a1i*j^4;
gc17:=j^8*a1i*a1i*a2i*j^4*a3*a1*a2*a1;
gc19:=a2i*a1*a3*a1i*a3i*a3i*j^4*a1*a2*j^4*a1i*a2i*j^4;
gc2:=j^4*gc1*j^8;
gc4:=j^4*gc3*j^8;
gc6:=j^4*gc5*j^8;
gc8:=j^4*gc7*j^8;
gc10:=j^4*gc9*j^8;
gc11:=j^4*gc10*j^8;
gc13:=j^4*gc12*j^8;
gc14:=j^4*gc13*j^8;
gc16:=j^4*gc15*j^8;
gc18:=j^4*gc17*j^8;
gc20:=j^4*gc19*j^8;

Picgeneratorlist:=[ G | gc1,gc2,gc3,gc4,gc5,gc6,gc7,gc8,gc9,gc10,gc11,gc12,gc13,gc14,gc15,gc16,gc17,gc18,gc19,gc20];

// To show that $h\pi h^{-1}\in\Pi$ for all $\pi\in\Pi_c$, it is enough
// to show that $h gc_i h^{-1} \in \Pi$ for $i=1,\ldots,20$ and for all
// $h$ is the transversal $\{b^\mu k:\mu=0,1,-1, k\in K\}$ of $\Pi$ in~$\bar\Gamma$.

print "Checking that h Pi_c h^-1 is contained in Pi_c for all h in barGamma.";
for ii in [1 .. #Pitransversal] do
 if IsDivisibleBy(ii,100) then print "Up to ii =",ii," out of 864"; end if;
 for jj in [1 .. 20] do
  testgp:=sub< G | a1,a2,a3,Pitransversal[ii]*Picgeneratorlist[jj]*Pitransversal[ii]^-1>;
  if (Index(G,testgp) lt 864) then print ii,jj; end if;
 end for;
end for;
print "Finished checking that for each generator g_i of Pi_c,";
print "and for each h in barGamma, h*g_i*h^-1 is in Pi.";

// We then need to show that $k_\alpha\Pi_ck_\alpha^{-1}=\Pi_\alpha$ for
// each $\alpha\in\{c_{+++},\ldots,c_{---}\}$.
// Here are the 8 elements $k_\alpha$ given in Lemma 2 for these $\alpha$'s:
kppp:=v^2*ui*v^2*u;
kppm:=v^3*ui*v^2*u;
kpmp:=v^3;
kpmm:=Id(G);
kmpp:=ui*v^2*u;
kmpm:=v*ui*v^2*u;  
kmmp:=v;
kmmm:=v^2;

// The following checks that $k_{-c}\Pi_ck_{-c}^{-1}=\Pi_{-c}$.
print "Finding the i1, i2 and i3 so that k_(-c)*t_i1*u^i2*j^i3*k_(-c)^(-1) is in Pi,";
print "where t_1,...,t_9 are the nine elements of PicKcdoublecosetreplist.";
for i1 in [1 .. 9] do
 for i2 in [0 .. 2] do
  for i3 in [0 .. 11] do
   transversalelt:=PicKcdoublecosetreplist[i1]*u^i2*j^i3;
   testgp:=sub< G | a1,a2,a3,kmmm*transversalelt*kmmm^-1>;
   idx:=Index(G,testgp);
   if (idx eq 864) then print "(i1,i2,i3)=(",i1,",",i2,",",i3,"), k_-c*transversalelt*k_-c^-1 is in Pi_c"; end if;
  end for;
 end for;
end for;
// Output: (1,0,0) only

// Calculation for Proposition 5(d):

// We now find all the transversal elements $t$ in the above transversal of $\Pi_c$
// in $\bar\Gamma_c$ such that $btb^{-1}\in\Pi_{b(M_c)}$ (or equivalently, such 
// that $btb^{-1}\in\Pi$).
print "Finding the i1, i2 and i3 so that b*t_i1*u^i2*j^i3*b^(-1) is in Pi,";
print "where t_1,...,t_9 are the nine elements  of PicKcdoublecosetreplist.";
for i1 in [1 .. 9] do
 for i2 in [0 .. 2] do
  for i3 in [0 .. 11] do
   transversalelt:=PicKcdoublecosetreplist[i1]*u^i2*j^i3;
   testgp:=sub< G | a1,a2,a3,b*transversalelt*bi>;
   idx:=Index(G,testgp);
   if (idx eq 864) then print "(i1,i2,i3)=(",i1,",",i2,",",i3,"), b*transversalelt*bi is in Pi_c"; end if;
  end for;
 end for;
end for;
// Output: (1,0,0),(6,2,8) and (8,2,6)

// We now find all the transversal elements $t$ in the above transversal of $\Pi_c$
// in $\bar\Gamma_c$ such that $b^{-1}tb\in\Pi_{b^{-1}(M_c)}$ (or equivalently, such 
// that $btb^{-1}\in\Pi$).
print "Finding the i1, i2 and i3 so that b^(-1)*k_(-c)*t_i1*u^i2*j^i3*k_(-c)^(-1)*b is in Pi,";
print "where t_1,...,t_9 are the nine elements of PicKcdoublecosetreplist.";
for i1 in [1 .. 9] do
 for i2 in [0 .. 2] do
  for i3 in [0 .. 11] do
   transversalelt:=PicKcdoublecosetreplist[i1]*u^i2*j^i3;
   testgp:=sub< G | a1,a2,a3,bi*transversalelt*b>;
   idx:=Index(G,testgp);
   if (idx eq 864) then print "(i1,i2,i3)=(",i1,",",i2,",",i3,"), bi*transversalelt*b is in Pi_c"; end if;
  end for;
 end for;
end for;
// Output: (1,0,0),(3,2,7),(5,0,9)

// End of calculations for Proposition 5.
// **************************************

// Calculations for the last bit of Section 2.4.
// *********************************************
// We give presentations of $\Pi_M$ for $M=b(M_c)$ and $M=b^{-1}(M_c)$.
// Firstly, we set up $\bar\Gamma_c$:

Fc<xt2,xt4,xt12,xzc>:=FreeGroup(4);
relnlistc:={
xt2^2,
xt4^4*xzc^-1,
xt12^12,
xzc^3,
xt12*xt4*xt2,
xt2*xzc*xt2^-1*xzc^-1,
xt4*xzc*xt4^-1*xzc^-1,
xt12*xzc*xt12^-1*xzc^-1};

Gammac,phic:=quo< Fc | relnlistc>;
t2:=phic(xt2);
t4:=phic(xt4);
t12:=phic(xt12);
zc:=phic(xzc);

// In the file cs-surface-matrices_magma.txt, we find elements $p_1,\ldots,p_8$
// belonging to $\Pi_{b(M_c)}$, and we exhibit each $b^{-1}p_ib$ as an element
// of $\bar\Gamma_c$ by expressing $b^{-1}p_ib$ as a word in the generators
// $t_2$, $t_4$, $t_{12}$ and $z_c$ of $\bar\Gamma_c$. We now check that
// the $b^{-1}p_ib$'s generate all of $b^{-1}\Pi_{b(M_c)}b$, by checking
// that the subgroup they generate has index 108 in~$\bar\Gamma_c$.
// Anticipating this result, we call the subgroup generated 
// by the $b^{-1}p_ib$'s subgroupbMc.
// That is, here is the group we check to be $b^{-1}\Pi_{b(M_c)}b$:
subgroupbMc:=sub< Gammac |
t12^9*t2*t12^11*t2*t12^8*zc,
t12^9*t2*t12^3*t2*t12^4*zc,
t12*t2*t12^11*t2*t12^4*zc,
t2*t12*t2*t12^7*zc^2,
t12^8*t2*t12^11*t2*t12^9*t2*t12^2,
t12^11*t2*t12^3*t2*t12^2*zc,
t12^10*t2*t12^11*t2*t12^2*t2*t12^3*zc^2,
t2*t12^11*t2*t12^10*t2*t12^5*zc^2>;

print "The index of subgroupbMc in Gammac is",Index(Gammac,subgroupbMc);  // Output: 108

// In the file cs-surface-matrices_magma.txt, we find elements $m_1,\ldots,m_8$
// belonging to $\Pi_{b^{-1}(M_c)}$, and we exhibit each $bm_ib^{-1}$ as an element
// of $\bar\Gamma_c$ by expressing $b^{-1}p_ib$ as a word in the generators
// $t_2$, $t_4$, $t_{12}$ and $z_c$ of $\bar\Gamma_c$. We now check that
// the $bm_ib^{-1}$'s generate all of $b\Pi_{b^{-1}(M_c)}b^{-1}$, by checking
// that the subgroup they generate has index 108 in~$\bar\Gamma_c$.
// Anticipating this result, we call the subgroup generated 
// by the $bm_ib^{-1}$'s subgroupbinvMc.
// That is, here is the group we check to be $b\Pi_{b^{-1}(M_c)}b^{-1}$:
subgroupbinvMc:=sub< Gammac |
t12^8*t2*t12^2*zc,
t2*t12^10*zc,
t12^6*t2*t12^8*zc^2,
t12^9*t2*t12^10*t2*t12^10*t2*t12,
t12^11*t2*t12^7*t2*t12^11*t2*t12,
t12^9*t2*t12^4*t2*t12^11,
t2*t12*t2*t12^3*t2*t12^11*t2*t12*zc,
t12^9*t2*t12^8*t2*t12^7>;

print "The index of subgroupbinvMc in Gammac is",Index(Gammac,subgroupbinvMc); // Output: 108

// Here is the subgroup $\Pi_c$, seen as a subgroup of $\bar\Gamma_c$
// by exhibiting each of the 20 generators $g_1,\ldots,g_{20}$ (defined in the
// proof of Proposition 4) as words in the generators of $\bar\Gamma_c$ given in Section 2.1.

Pic:=sub< Gammac | 
t12^6*t2*t12^4*t2*t12^2,
t12^10*t2*t12^4*t2*t12^10,
t12^8*t2*t12^4*t2,
t2*t12^4*t2*t12^8,
t12^5*t2*t12^4*t2*t12^3,
t12^9*t2*t12^4*t2*t12^11,
t12^11*t2*t12^4*t2*t12^9,
t12^3*t2*t12^4*t2*t12^5,
t12^5*t2*t12^10*t2*t12^10*t2*t12^5,
t12^9*t2*t12^10*t2*t12^10*t2*t12,
t12*t2*t12^10*t2*t12^10*t2*t12^9,
t12^6*t2*t12^10*t2*t12^10*t2*t12^4,
t12^10*t2*t12^10*t2*t12^10*t2,
t12^2*t2*t12^10*t2*t12^10*t2*t12^8,
t12^8*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^11*zc^2,
t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^7*zc^2,
t12^5*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^2*zc^2,
t12^9*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^10*zc^2,
t12^6*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12*zc^2,
t12^10*t2*t12^11*t2*t12^3*t2*t12^11*t2*t12^9*zc^2>;
// Checking that $\Pi_c$ is contained in $b^{-1}\Pi_M b$, where $M=b(M_c)$, 
// as a subgroup of index 3.
Index(subgroupbMc,Pic); // Output: 3

// Checking that $\Pi_c$ is contained in $b\Pi_M b^{-1}$, where $M=b^{-1}(M_c)$, 
// as a subgroup of index 3.
Index(subgroupbinvMc,Pic); // Output: 3

// We now want to get presentations for the groups $\Pi_M$, where $M=b(M_c)$
// // and $M=b^{-1}(M_c)$.
// // We do this using Rewrite.
// 
// R,f:=Rewrite(Gammac,subgroupbMc);
// R;
// "f(g1):=",f(subgroupbMc.1);
// "f(g2):=",f(subgroupbMc.2);
// "f(g3):=",f(subgroupbMc.3);
// "f(g4):=",f(subgroupbMc.4);
// "f(g5):=",f(subgroupbMc.5);
// "f(g6):=",f(subgroupbMc.6);
// "f(g7):=",f(subgroupbMc.7);
// "f(g8):=",f(subgroupbMc.8);'
// 
// // This tells us that subgroupbMc has a presentation with respect to
// // new generators R1,...,R8 satisfying just one relation:
// // R6*R8*R7*R4I*R2*R1*R2I*R5*R6I*R4*R8I*R7I*R1I*R3*R5I*R3I = Id(R)
// // These generators Ri can be expressed in terms of the generators
// // of the ambient group $\Gamma_c$ as follows:
// R1:=t2*t12^-1*t4*t12*t4^-1*t2;
// R2:=t4*t12^-1*t4*zc*t12*t2;
// R3:=t4^-1*t12*t2*zc^-1*t12^-1*t4^-1;
// R4:=t4^2*t12^2*t4^-1*t2*t12^-1;
// R5:=t4*t12^2*t2*t4*t12^-1*t4^-1;
// R6:=t4^-1*t2*t12^-1*t4*t12^-1*t4^-1*t12;
// R7:=t12*t2*zc*t12^-1*t4*t12*t2*t12^-2;
// R8:=t12^3*t4^-1*t12*t4^-1*t12*t2*t12^-1;
// // Writing 
// R1I:=R1^-1;
// R2I:=R2^-1;
// R3I:=R3^-1;
// R4I:=R4^-1;
// R5I:=R5^-1;
// R6I:=R6^-1;
// R7I:=R7^-1;
// R8I:=R8^-1;
// 
// // Let us write $Q_i$ for the generators $b^{-1}p_ib$ of the group $b^{-1}\Pi_{b(M_c)}b$,
// // 
// Q1:=BI*P1*B;
// Q2:=BI*P2*B;
// Q3:=BI*P3*B;
// Q4:=BI*P4*B;
// Q5:=BI*P5*B;
// Q6:=BI*P6*B;
// Q7:=BI*P7*B;
// Q8:=BI*P8*B;
// 
// // and their inverses:
// Q1I:=BI*P1I*B;
// Q2I:=BI*P2I*B;
// Q3I:=BI*P3I*B;
// Q4I:=BI*P4I*B;
// Q5I:=BI*P5I*B;
// Q6I:=BI*P6I*B;
// Q7I:=BI*P7I*B;
// Q8I:=BI*P8I*B;
// // the equations "f(g_i)=f(subgroupbMc.i);" give formulas of the form
// // Qi = word in R1,...,R8, namely (in matrix terms):
// Q1 := R8*R7*R4I*R2*R1*R2I*R5*R6I*R4*R8I*R7I*R1I*R3*R5I*R3I*Q4;
// Q2 := R8*R7*R4I*R2*R1*R2I*R5*R6I*R4*R8I*R7I*R4I*Q4;
// Q3 := R1I*R3*(1/z^4)*Q7*R8*R7*R4I*R2*R1*R2I*R5*R6I*R4*R8I*R7I*R4I*Q4;
// Q4 := (1/z^4)*R6*R5I*R2*R1I*R2I*R4*R7I*R8I;
// Q5 := (z^4)*R8*R7*R4I*R2*R1*R2I*R5*R6I*R4*R1I*R3*Q7*R8*R7*R4I*R2*R1*R2I*R5*R6I*R4*R8I*R4I*R2*R1*R2I*R5;
// Q6 := R5;
// Q7 := z^4*R5I*R3I*R6;
// Q8 := z^4*R3*Q7*R8*R7*R4I*R2*R1*R2I*R5*R6I*R4*R8I*R7I*R1I*R1I*R2I*Q4;
// 
// // We can solve this for the Ri's in terms of the Qi's (working with matrices, for example),
// // obtaining the following being zero:
// 
// R1 - Q4*Q1I*Q7I*Q6I*Q7*Q2*Q3I;
// R2 - (1/z^4)*Q4*Q8I*Q3*Q2I*Q7I*Q6*Q7*Q1*Q4I;
// R3 - z^4*Q4*Q1I*Q7I*Q6I;
// R4 - Q4*Q3I;
// R5 - Q6;
// R6 - Q4*Q1I;
// R7 - (1/z^4)*Q3*Q2I*Q5*Q1;
// R8 - Q1I*Q5I*Q3I;
// 
// R1I - Q3*Q2I*Q7I*Q6*Q7*Q1*Q4I;
// R2I - z^4*Q4*Q1I*Q7I*Q6I*Q7*Q2*Q3I*Q8*Q4I;
// R3I - (1/z^4)*Q6*Q7*Q1*Q4I;
// R4I - Q3*Q4I;
// R5I - Q6I;
// R6I - Q1*Q4I;
// R7I - z^4*Q1I*Q5I*Q2*Q3I;
// R8I - Q3*Q5*Q1;
// 
// // When we substitute these formulas for the Ri's into the single
// // relation of the presentation for subgroupbMc in terms of the Ri's,
// // and after cancelling the Qi*QiI's and QiI*Qi's, we obtain (after a conjugation)
// // the relation
// // Q5I*Q2I*Q5*Q1*Q3*Q8I*Q4*Q1I*Q7I*Q6I*Q7*Q2*Q3I*Q8*Q4I*Q6 = Id
// // given in Section 2.4.
// 
// // While we're at it, we repeat this for the group $b\Pi_{b^{-1}(M_c)}b^{-1}$
// 
// R,f:=Rewrite(Gammac,subgroupbinvMc);
// R;
// "f(g1):=",f(subgroupbinvMc.1);
// "f(g2):=",f(subgroupbinvMc.2);
// "f(g3):=",f(subgroupbinvMc.3);
// "f(g4):=",f(subgroupbinvMc.4);
// "f(g5):=",f(subgroupbinvMc.5);
// "f(g6):=",f(subgroupbinvMc.6);
// "f(g7):=",f(subgroupbinvMc.7);
// "f(g8):=",f(subgroupbinvMc.8);
// 
// // This tells us that subgroupbinvMc has a presentation with respect to
// // new generators R1,...,R8 satisfying just one relation:
// R3I*R8I*R7I*R3*R2I*R1I*R2*R7*R4I*R8*R6*R5I*R6I*R5*R1*R4 = Id(R)
// / These generators Ri can be expressed in terms of the generators
// // of the ambient group $\Gamma_c$ as follows:
// 
// R1:=t12^2*zc^-1*t2;
// R2:=(t12*t4^-1)^3;
// R3:=t4*t12^5*t4^-2;
// R4:=t4^-1*t12^3*t2*t12^-1*t4*zc^-1;
// R5:=t12^-1*t4*t12*t2*t4^-1*t12^2*zc^-1;
// R6:=t4*t12^2*t4^-1*t2*t4^-2*t12^2;
// R7:=t4*t12^-1*t4*t12*t2*t4*t12^-2*t4;
// R8:=t4^-1*t12*t2*t4^2*t12*t2*t12^-2*t4^-1;
// 
// // Writing 
// R1I:=R1^-1;
// R2I:=R2^-1;
// R3I:=R3^-1;
// R4I:=R4^-1;
// R5I:=R5^-1;
// R6I:=R6^-1;
// R7I:=R7^-1;
// R8I:=R8^-1;
// 
// // Let us write $Q_i$ for the generators $bm_ib^{-1}$ of the group $b\Pi_{b^{-1}(M_c)}b^{-1}$,
// // 
// Q1:=B*M1*BI;
// Q2:=B*M2*BI;
// Q3:=B*M3*BI;
// Q4:=B*M4*BI;
// Q5:=B*M5*BI;
// Q6:=B*M6*BI;
// Q7:=B*M7*BI;
// Q8:=B*M8*BI;
// 
// Q1I:=Q1^-1;
// Q2I:=Q2^-1;
// Q3I:=Q3^-1;
// Q4I:=Q4^-1;
// Q5I:=Q5^-1;
// Q6I:=Q6^-1;
// Q7I:=Q7^-1;
// Q8I:=Q8^-1;
// 
// The lines "f(gi)=",f(subgroupbinvMc.i); give us equations for
// the old generators in terms of the new ones. We can verify these
// using matrices.  The following are zero:
// Q1 - z^4*R5I;
// Q2 - z^4*R1I;
// Q3 - (1/z^4)*R1*R4*R1I;
// Q4 - R6I*R3*R2I*R1I*R2*R7*R4I*R8*R6*R5I*R6I*R5*R1*R4*R3I*R8I*R7I;
// Q5 - R3*R2I*R1I*R2*R7*R4I*R8*R6*R5I*R6I*R3*R2I*R1I*R2*R7*R4I*R8*R6*R5I*R6I*R5*R1*R4*R3I*R8I*R7I;
// Q6 - (1/z^4)*R6I*R8I*R4*R7I*R2I;
// Q7 - R2I*R1I*R2*R7*R4I*R8*R6*R5I*R6I*R3*R2I*R1I*R2*R7*R4I*R8*R6*R5I*R6I*R5*R1*R4*R3I*R8I*R7I;
// Q8 - z^4*R6I*R8I*R1I;
// 
// Using matrices as an aid, we can solve these relations for the Ri in terms of the Qi's:
// // The following are zero:
// R1 - z^4*Q2I;
// R2 - Q2*Q6I*Q1*Q4*Q7I;
// R3 - Q5*Q7I;
// R4 - z^4*Q2*Q3*Q2I;
// R5 - z^4*Q1I;
// R6 - Q4I;
// R7 - Q7*Q4I*Q1I*Q6*Q2I*Q6I*Q8*Q3*Q2I;
// R8 - Q2*Q8I*Q4;
// 
// R1I - (1/z^4)*Q2;
// R2I - Q7*Q4I*Q1I*Q6*Q2I;
// R3I - Q7*Q5I;
// R4I - (1/z^4)*Q2*Q3I*Q2I;
// R5I - (1/z^4)*Q1;
// R6I - Q4;
// R7I - Q2*Q3I*Q8I*Q6*Q2*Q6I*Q1*Q4*Q7I;
// R8I - Q4I*Q8*Q2I;
// 
// // When we substitute these formulas for the Ri's into the relation
// // in R1,...,R8 found by Rewrite, and make the cancellations of the 
// // Qi*QiI's and QiI*Qi's, we get the relation
// Q3*Q8I*Q4*Q5*Q7I*Q2*Q3I*Q1*Q5I*Q7*Q4I*Q1I*Q6*Q2I*Q6I*Q8 = Id
// // or equivalently, the relation
// M3*M8I*M4*M5*M7I*M2*M3I*M1*M5I*M7*M4I*M1I*M6*M2I*M6I*M8 = Id
// 
// End of the calculations about the last bit of Section 2.4.
// **********************************************************

// Calculations for Proposition 6:
// *******************************
// The following are representatives for the distinct double cosets
// $\Pi_0 g K_0$ in $\bar\Gamma_0$:
rep01:=Id(G);
rep02:=j^9*b*j^7;
rep03:=j^10*b*j^7;
rep04:=j^11*b*j^7;
rep05:=b*j^7;
rep06:=j^9*b*j^2*bi*j;

kplus1:=v^3*u*j;
kinfty:=ui*v^2*u*j^6;

// The following are representatives for the distinct double cosets
// $\Pi_1 g K_1$ in $\bar\Gamma_1$:
rep11:=kplus1*rep01*kplus1^-1;
rep12:=kplus1*rep02*kplus1^-1;
rep13:=kplus1*rep03*kplus1^-1;
rep14:=kplus1*rep04*kplus1^-1;
rep15:=kplus1*rep05*kplus1^-1;
rep16:=kplus1*rep06*kplus1^-1;

// The following are representatives for the distinct double cosets
// $\Pi_\infty g K_\infty$ in $\bar\Gamma_\infty$:
repinfty1:=kinfty*rep01*kinfty^-1;
repinfty2:=kinfty*rep02*kinfty^-1;
repinfty3:=kinfty*rep03*kinfty^-1;
repinfty4:=kinfty*rep04*kinfty^-1;
repinfty5:=kinfty*rep05*kinfty^-1;
repinfty6:=kinfty*rep06*kinfty^-1;

doublereplist:=[ G | rep01,rep02,rep03,rep04,rep05,rep06,
rep11,rep12,rep13,rep14,rep15,rep16,
repinfty1,repinfty2,repinfty3,repinfty4,repinfty5,repinfty6];
namelist:=["0","1","infty"];

for ii in [1 .. 18] do
 fl:=Floor((ii-1)/6);
 for jj in [1 .. #kklist] do
  for mu in [0,1,-1] do
   testgp:=sub< G | a1,a2,a3,doublereplist[ii]*kklist[jj]^-1*b^(-mu)>;
   if (Index(G,testgp) eq 864) then print "rep",namelist[fl+1],ii-6*fl,"is in Pi*b^",mu,"*",kkwordlist[jj]; end if;
  end for;
 end for;
end for;

// Cleaned up output:
// rep01 is in Pi*b^0*[]
// rep02 is in Pi*b^-1*[v*j*j]
// rep03 is in Pi*b^0*[v*u*j*j*j*j*j*j*j*j]
// rep04 is in Pi*b^-1*[ui*v*v*u*j]
// rep05 is in Pi*b^1*[j*j*j*j*j*j*j]
// rep06 is in Pi*b^0*[u*v*v*j*j*j*j]
// rep11 is in Pi*b^0*[]
// rep12 is in Pi*b^1*[u*vi*j*j]
// rep13 is in Pi*b^1*[vi*u*vi*j*j*j]
// rep14 is in Pi*b^1*[u*v*v*ui]
// rep15 is in Pi*b^1*[v*j*j*j*j]
// rep16 is in Pi*b^-1*[v*u*vi*j*j*j]
// repinfty1 is in Pi*b^0*[]
// repinfty2 is in Pi*b^-1*[v*v*ui*j*j*j*j*j*j*j*j*j*j]
// repinfty3 is in Pi*b^-1*[u*v*v*j*j*j*j*j*j*j]
// repinfty4 is in Pi*b^0*[u*v*v*j*j*j*j*j*j]
// repinfty5 is in Pi*b^1*[v*v*j*j*j*j]
// repinfty6 is in Pi*b^-1*[v*u*j*j*j*j*j*j]

// In the file cs-surface_matrices_magma.txt, these assertions are 
// checked with matrices.

// End of calculations for Proposition 6.
// **************************************

// Calculations for Proposition 7:
// *******************************
// Here are double coset representatives for the double cosets
// $\Pi_c g K_c$, $g\in\bar\Gamma_c$.
repc1:=Id(G);
repc2:=j^7*b*ui*b*u*j^7;
repc3:=j^8*b*ui*b*u*j^7;
repc4:=j^9*b*ui*b*u*j^7;
repc5:=j^10*b*ui*b*u*j^7;
repc6:=j^7*b*ui*b*u*j^11*b*ui*b*ui*j^2;
repc7:=j^8*b*ui*b*u*j^11*b*ui*b*ui*j^2;
repc8:=j^9*b*ui*b*u*j^11*b*ui*b*ui*j^2;
repc9:=j^10*b*ui*b*u*j^11*b*ui*b*ui*j^2;

// Here are double coset representatives for the double cosets
// $\Pi_{-c} g K_{-c}$, $g\in\bar\Gamma_{-c}$.
repmc1:=kmmm*repc1*kmmm^-1;
repmc2:=kmmm*repc2*kmmm^-1;
repmc3:=kmmm*repc3*kmmm^-1;
repmc4:=kmmm*repc4*kmmm^-1;
repmc5:=kmmm*repc5*kmmm^-1;
repmc6:=kmmm*repc6*kmmm^-1;
repmc7:=kmmm*repc7*kmmm^-1;
repmc8:=kmmm*repc8*kmmm^-1;
repmc9:=kmmm*repc9*kmmm^-1;

doublereplist:=[ G | repc1,repc2,repc3,repc4,repc5,repc6,repc7,repc8,repc9,
repmc1,repmc2,repmc3,repmc4,repmc5,repmc6,repmc7,repmc8,repmc9];
namelist:=["c","mc"];
for ii in [1 .. 18] do
 fl:=Floor((ii-1)/9);
 for jj in [1 .. #kklist] do
  for mu in [0,1,-1] do
   testgp:=sub< G | a1,a2,a3,doublereplist[ii]*kklist[jj]^-1*b^(-mu)>;
   if (Index(G,testgp) eq 864) then print "rep",namelist[fl+1],ii-9*fl,"is in Pi*b^",mu,"*",kkwordlist[jj]; end if;
  end for;
 end for;
end for;
// Cleaned up output:

// repc1 is in Pi*b^0*[]
// repc2 is in Pi*b^1*[v,ui,v,j,j,j,j,j,j,j,j,j]
// repc3 is in Pi*b^1*[vi,u,vi]
// repc4 is in Pi*b^-1*[v,ui,j,j,j,j,j,j,j,j,j]
// repc5 is in Pi*b^-1*[v,v,u,j,j,j,j,j,j]
// repc6 is in Pi*b^0*[v,ui,v,j,j]
// repc7 is in Pi*b^0*[u,vi,j,j,j,j,j]
// repc8 is in Pi*b^1*[v,v,ui,j,j]
// repc9 is in Pi*b^0*[v,u,j,j,j,j,j,j,j]
// 
// repmc1 is in Pi*b^0*[]
// repmc2 is in Pi*b^-1*[u,v,j,j,j,j,j,j]
// repmc3 is in Pi*b^0*[ui,v,v,u,j,j,j,j,j,j,j]
// repmc4 is in Pi*b^1*[v]
// repmc5 is in Pi*b^0*[u,vi,u,j,j,j,j,j,j,j,j]
// repmc6 is in Pi*b^-1*[ui,v,v,u,j,j,j,j,j]
// repmc7 is in Pi*b^1*[ui,v,j]
// repmc8 is in Pi*b^1*[v,ui,v,v,u]
// repmc9 is in Pi*b^0*[v,j,j,j,j,j,j]
// 
// We now show that the following list of 3 elements is a set of double coset
// representatives for $b^{-1}\Pi_{b(M_c)}b\backslash(\bar\Gamma_c)/K_c$:
binvPibMcbKcdoublecosetreplist:=[Gammac | Id(Gammac),t2,t4];
// by showing that the following list of 108 elements is a transversal
// for $b^{-1}\Pi_{b(M_c)}b$ in $\bar\Gamma_c$:

// The group $K_c=K\cap\bar\Gamma$ is generated by $u$ and $j$. In terms
// of generators $t_2$, $t_4$, $t_{12}$ of Section 2.1, the two generators
// of $K_c$ are $z_c$ and $t_{12}$, respectively.

Kclistingammac:=[ Gammac | zc^i1*t12^i2 : i1 in [0 .. 2], i2 in [0 .. 11]];
binvPibMcbingammactransversal:=[ Gammac | binvPibMcbKcdoublecosetreplist[i1]*Kclistingammac[i2] : i1 in [1 .. 3], i2 in [1 .. 36]];

print "Checking that binvPibMcbingammactransversal is indeed a transversal for b^-1(Pi_(b(M_c))b in barGamma_c";
print "by checking that the elements are in different cosets of barGamma_c.";
for i1 in [1 .. 108] do
 if IsDivisibleBy(i1,10) then print "Up to ",i1," out of 108"; end if;
 for i2 in [i1+1 .. 108] do
  testgp:=sub< Gammac | // the first 8 generators here are those of $b^{-1}\Pi_{b(M_c)}b$
   t12^9*t2*t12^11*t2*t12^8*zc,
   t12^9*t2*t12^3*t2*t12^4*zc,
   t12*t2*t12^11*t2*t12^4*zc,
   t2*t12*t2*t12^7*zc^2,
   t12^8*t2*t12^11*t2*t12^9*t2*t12^2,
   t12^11*t2*t12^3*t2*t12^2*zc,
   t12^10*t2*t12^11*t2*t12^2*t2*t12^3*zc^2,
   t2*t12^11*t2*t12^10*t2*t12^5*zc^2,
   binvPibMcbingammactransversal[i1]*binvPibMcbingammactransversal[i2]^-1>;
  idx:=Index(Gammac,testgp);
  if (idx eq 108) then print "Problem: For i1 =",i1,"and i2=",i2,"the index of testgp in G is 108"; end if;
 end for;
end for;

// We now show that the following list of 3 elements is a set of double coset
// representatives for $b\Pi_{b^{-1}(M_c)}b^{-1}\backslash(\bar\Gamma_c)/K_c$:
bPibinvMcbinvKcdoublecosetreplist:=[Gammac | Id(Gammac),t4,t2*t4];
// by showing that the following list of 108 elements is a transversal
// for $b\Pi_{b^{-1}(M_c)}b^{-1}$ in $\bar\Gamma_c$:

bPibinvMcbinvingammactransversal:=[ Gammac | bPibinvMcbinvKcdoublecosetreplist[i1]*Kclistingammac[i2] : i1 in [1 .. 3], i2 in [1 .. 36]];

print "Checking that bPibinvMcbinvingammactransversal is indeed a transversal for b(Pi_(b^-1(M_c))b^-1 in barGamma_c";
print "by checking that the elements are in different cosets of barGamma_c.";
for i1 in [1 .. 108] do
 if IsDivisibleBy(i1,10) then print "Up to ",i1," out of 108"; end if;
 for i2 in [i1+1 .. 108] do
  testgp:=sub< Gammac | // the first 8 generators here are those of $b\Pi_{b^{-1}(M_c)}b^{-1}$
   t12^8*t2*t12^2*zc,
   t2*t12^10*zc,
   t12^6*t2*t12^8*zc^2,
   t12^9*t2*t12^10*t2*t12^10*t2*t12,
   t12^11*t2*t12^7*t2*t12^11*t2*t12,
   t12^9*t2*t12^4*t2*t12^11,
   t2*t12*t2*t12^3*t2*t12^11*t2*t12*zc,
   t12^9*t2*t12^8*t2*t12^7,
   bPibinvMcbinvingammactransversal[i1]*bPibinvMcbinvingammactransversal[i2]^-1>;
  idx:=Index(Gammac,testgp);
  if (idx eq 108) then print "Problem: For i1 =",i1,"and i2=",i2,"the index of testgp in G is 108"; end if;
 end for;
end for;

// Thinking of the three elements of binvPibMcbKcdoublecosetreplist as elements
// of $\bar\Gamma$, they are 1, (b*u^-1)^2 and j^-1*(b*u^-1)^2. So we re-define
binvPibMcbKcdoublecosetreplist:=[G | Id(G),(b*u^-1)^2,j^-1*(b*u^-1)^2];
// So the representatives for the double cosets $\Pi_{b(M_c)}\backslash\bar\Gamma_{b(M_c)}/bK_cb^{-1}$
// are $b\gamma b^{-1}$ for these three elements~$\gamma$. We need to find $\mu\in\{0,1,-1\}$ and $k\in K$
// so that $b\gamma\in\Pi b^\mu k$ for each of these $\gamma$'s.

for ii in [1 .. 3] do
 for jj in [1 .. #kklist] do
  for mu in [0,1,-1] do
   testgp:=sub< G | a1,a2,a3,b*binvPibMcbKcdoublecosetreplist[ii]*kklist[jj]^-1*b^(-mu)>;
   if (Index(G,testgp) eq 864) then print "b*rep",ii,"is in Pi*b^",mu,"*",kkwordlist[jj]; end if;
  end for;
 end for;
end for;

// Output:
// b*rep1 is in Pi*b^1*[]
// b*rep2 is in Pi*b^(-1)*[vi,u,v,v,j,j,j,j,j,j,j,j,j,j,j]
// b*rep3 is in Pi*b^(-1)*[v,u,vi,j]
// So $n_0(M)=0$, $n_1(M)=1$ and $n_{-1}(M)=2$ for $M=b(M_c)$.
// These facts are confirmed by matrix calculations in the file cs-surface_matrices_magma.txt

// Thinking of the three elements of bPibinvMcbinvKcdoublecosetreplist as elements
// of $\bar\Gamma$, they are 1, j^-1*(b*u^-1)^2 and (b*u^-1)^2*j^-1*(b*u^-1)^2. So we re-define
bPibinvMcbinvKcdoublecosetreplist:=[G | Id(G),j^-1*(b*u^-1)^2, (b*u^-1)^2*j^-1*(b*u^-1)^2];
// So the representatives for the double cosets $\Pi_{b^{-1}(M_c)}\backslash\bar\Gamma_{b^{-1}(M_c)}/(b^{-1}K_cb)$
// are $b^{-1}\gamma b$ for these three elements~$\gamma$. We need to find $\mu\in\{0,1,-1\}$ and $k\in K$
// so that $b^{-1}\gamma\in\Pi b^\mu k$ for each of these $\gamma$'s.

for ii in [1 .. 3] do
 for jj in [1 .. #kklist] do
  for mu in [0,1,-1] do
   testgp:=sub< G | a1,a2,a3,b^(-1)*bPibinvMcbinvKcdoublecosetreplist[ii]*kklist[jj]^-1*b^(-mu)>;
   if (Index(G,testgp) eq 864) then print "b^(-1)*rep",ii,"is in Pi*b^",mu,"*",kkwordlist[jj]; end if;
  end for;
 end for;
end for;
// Output:
// b^(-1)*rep1 is in Pi*b^-1*[]
// b^(-1)*rep2 is in Pi*b^1*[v,v,u,vi,j,j,j,j,j]
// b^(-1)*rep3 is in Pi*b^-1*[vi,j,j,j,j,j,j,j,j]
// So $n_0(M)=0$, $n_1(M)=1$ and $n_{-1}(M)=2$ for $M=b^{-1}(M_c)$.
// These facts are confirmed by matrix calculations in the file cs-surface_matrices_magma.txt.

// End of calculations for Proposition 7.
// **************************************

// Calculations for Proposition 8.
// *******************************

// The distinct points $\Pi\xi\in\Pi\backslash B(\C^2)$ which project
// to $P_3$ are the points $\Pi t_i\xi_{12}$, where $\xi_{12}\in B(\C^2)$
// is the fixed point of $\gamma_{12}=bv$, and where $t_1,\ldots,t_{72}$
// is a set of representatives for the double cosets 
// $\Pi g\langle\gamma_{12}\rangle$, $g\in\bar\Gamma$.
// We found the following list of 72 elements, and check below that
// they form a complete set of representatives. The list is divided
// into 3 sublists of length 24, in line with the statement of Proposition 8.

gamma12doublecosetlist:=[ G |
j^2,j^6,j^10,
u*j,u*j^5,u*j^9,
Id(G),j^4,j^8,
u*j^3,u*j^7,u*j^11,
j,j^5,j^9,
u*j^2,u*j^6,u*j^10,
j^3,j^7,j^11,
u,u*j^4,u*j^8,
//
vi*u*j,vi*u*j^5,vi*u*j^9,
vi*u*j^3,vi*u*j^7,vi*u*j^11,
b*u,b*u*j^4,b*u*j^8,
vi*u*j^2,vi*u*j^6,vi*u*j^10,
b*u*j,b*u*j^5,b*u*j^9,
b*v*u*j,b*v*u*j^5,b*v*u*j^9,
b*vi*u*j,b*vi*u*j^5,b*vi*u*j^9,
vi*u,vi*u*j^4,vi*u*j^8,
//
v*ui*j,v*ui*j^5,v*ui*j^9,
v*ui*j^2,v*ui*j^6,v*ui*j^10,
u*vi*u*j,u*vi*u*j^5,u*vi*u*j^9,
b^-1*v*u*j^2,b^-1*v*u*j^6,b^-1*v*u*j^10,
v*ui,v*ui*j^4,v*ui*j^8,
v*ui*j^3,v*ui*j^7,v*ui*j^11,
u*vi*u,u*vi*u*j^4,u*vi*u*j^8,
b*v*ui*v*v*u*j,b*v*ui*v*v*u*j^5,b*v*ui*v*v*u*j^9];
 
gamma12:=b*v;
gamma12pitransversal:=[ G | gamma12doublecosetlist[j1]*gamma12^j2: j1 in [1 .. 72], j2 in [0 .. 11]];

print "Checking that gamma12pitransversal is indeed a transversal for Pi in barGamma";
print "This takes a few minutes. Progress seems slow at first, but it gets faster.";
for i1 in [1 .. 864] do
 if IsDivisibleBy(i1,10) then print "Up to ",i1," out of ",864; end if;
 for i2 in [i1+1 .. 864] do
  testgp:=sub< G | a1,a2,a3,gamma12pitransversal[i1]*gamma12pitransversal[i2]^-1>;
  idx:=Index(G,testgp);
  if (idx eq 864) then print "Problem: For i1 =",i1,"and i2=",i2,"the index of testgp in G is 864"; end if;
 end for;
end for;

// End of calculations for Proposition 8.
// **************************************

// Calculations for Proposition 11.
// ********************************
// Here is a the list of representatives of nontrivial elements of finite
// order in $\bar\Gamma$. Each nontrivial element of $\bar\Gamma$ is conjugate
// the one of the elements in the list, or their inverse.

torsionreplist:=[ G |
// order 2:
 v*v,
j*j*j*j*j*j,
b*ui*b*ui,
// order3:
u,
j*j*j*j,
u*j*j*j*j,
b*u*v,
// order 4:
v,
j*j*j,
v*j*j*j,
v*v*j*j*j,
b*ui,
// order 6:
j*j,
v*v*j*j,
v*v*u*j,
v*v*u*j*j*j*j*j,
b*v*v*ui*j,
b*v*v,
//order 8:
u*v*j,
b*j,
(b*j)^3,
// order 12:
j,
j*j*j*j*j,
u*vi*j*j,
u*vi*j*j*j,
u*vi*j*j*j*j*j*j,
u*vi*j*j*j*j*j*j*j*j*j*j*j,
v*v*j,
u*v*v,
u*j,
u*j*j*j,
b*v,
(b*v)^(-5),
// order 24:
u*v,
v*u*j*j];

torsionrepwordlist:=[
// order 2:
["v*v"],
["j*j*j*j*j*j"],
["b*ui*b*ui"],
// order 3:
["u"],
["j*j*j*j"],
["u*j*j*j*j"],
["b*u*v"],
// order 4:
["v"],
["j*j*j"],
["v*j*j*j"],
["v*v*j*j*j"],
["b*ui"],
// order 6:
["j*j"],
["v*v*j*j"],
["v*v*u*j"],
["v*v*u*j*j*j*j*j"],
["b*v*v*ui*j"],
["b*v*v"],
//order 8:
["u*v*j"],
["b*j"],
["(b*j)^3"],
// order 12:
["j"],
["j*j*j*j*j"],
["u*vi*j*j"],
["u*vi*j*j*j"],
["u*vi*j*j*j*j*j*j"],
["u*vi*j*j*j*j*j*j*j*j*j*j*j"],
["v*v*j"],
["u*v*v"],
["u*j"],
["u*j*j*j"],
["b*v"],
["(b*v)^(-5)"],
// order 24:
["u*v"],
["v*u*j*j"]];

print "Finding mu in {0,1,-1} and k in K and t from the representative list of elements";
print "of finite order given in Proposition 11 (or the inverse of one of these t's),";
print "so that b^mu*k*t*k^-1*b^(-mu)*j^(-4) is in Pi. We exclude the case t=j^4 or its inverse.";
for tidx in [1 .. #torsionreplist] do
 if (tidx ne 5) then // We want to treat the case j^4 separately.
  for mu in [0,1,-1] do
   for ii in [1 .. 288] do
    testgp:=sub< G | a1,a2,a3,b^mu*kklist[ii]*torsionreplist[tidx]*kklist[ii]^-1*b^(-mu)*j^(-4)>;
    idx:=Index(G,testgp);
    if (idx eq 864) then print "b^",mu,"*",kkwordlist[ii],"*",torsionrepwordlist[tidx],"*",kkwordlist[ii],"^-1*b^",-mu,"*j^-4 is in Pi"; end if;
    testgp:=sub< G | a1,a2,a3,b^mu*kklist[ii]*torsionreplist[tidx]^-1*kklist[ii]^-1*b^(-mu)*j^(-4)>;
    idx:=Index(G,testgp);
    if (idx eq 864) then print "b^",mu,"*",kkwordlist[ii],"*",torsionrepwordlist[tidx],"^(-1)*",kkwordlist[ii],"^-1*b^",-mu,"*j^-4 is in Pi"; end if;
   end for;
  end for;
 end if;
end for;

// Tidied up output:
// b^0*(ui*v*j)*(b*u*v)*(ui*v*j)^-1*b^0*j^-4 is in Pi
// b^0*(ui*v*j*j*j*j*j)*(b*u*v)*(ui*v*j*j*j*j*j)^-1*b^0*j^-4 is in Pi
// b^0*(ui*v*j*j*j*j*j*j*j*j*j)*(b*u*v)*(ui*v*j*j*j*j*j*j*j*j*j)^-1*b^0*j^-4 is in Pi
// 
// b^0*(v*j*j)*(b*u*v)*(v*j*j)^-1*b^0*j^-4 is in Pi
// b^0*(v*j*j*j*j*j*j)*(b*u*v)*(v*j*j*j*j*j*j)^-1*b^0*j^-4 is in Pi
// b^0*(v*j*j*j*j*j*j*j*j*j*j)*(b*u*v)*(v*j*j*j*j*j*j*j*j*j*j)^-1*b^0*j^-4 is in Pi
// 
// b^1*(v*ui*v)*(b*u*v)*(v*ui*v)^-1*b^-1*j^-4 is in Pi
// b^1*(v*ui*v*j*j*j*j)*(b*u*v)*(v*ui*v*j*j*j*j)^-1*b^-1*j^-4 is in Pi
// b^1*(v*ui*v*j*j*j*j*j*j*j*j)*(b*u*v)*(v*ui*v*j*j*j*j*j*j*j*j)^-1*b^-1*j^-4 is in Pi
// 
// b^1*(u*v*v*j*j)*(b*u*v)*(u*v*v*j*j)^-1*b^-1*j^-4 is in Pi
// b^1*(u*v*v*j*j*j*j*j*j)*(b*u*v)*(u*v*v*j*j*j*j*j*j)^-1*b^-1*j^-4 is in Pi
// b^1*(u*v*v*j*j*j*j*j*j*j*j*j*j)*(b*u*v)*(u*v*v*j*j*j*j*j*j*j*j*j*j)^-1*b^-1*j^-4 is in Pi
// 
// b^-1*(v*u*j*j*j)*(b*u*v)*(v*u*j*j*j)^-1*b^1*j^-4 is in Pi
// b^-1*(v*u*j*j*j*j*j*j*j)*(b*u*v)*(v*u*j*j*j*j*j*j*j)^-1*b^1*j^-4 is in Pi
// b^-1*(v*u*j*j*j*j*j*j*j*j*j*j*j)*(b*u*v)*(v*u*j*j*j*j*j*j*j*j*j*j*j)^-1*b^1*j^-4 is in Pi
// 
// b^-1*(v*v*u*j*j*j)*(b*u*v)*(v*v*u*j*j*j)^-1*b^1*j^-4 is in Pi
// b^-1*(v*v*u*j*j*j*j*j*j*j)*(b*u*v)*(v*v*u*j*j*j*j*j*j*j)^-1*b^1*j^-4 is in Pi
// b^-1*(v*v*u*j*j*j*j*j*j*j*j*j*j*j)*(b*u*v)*(v*v*u*j*j*j*j*j*j*j*j*j*j*j)^-1*b^1*j^-4 is in Pi

print "Finding mu in {0,1,-1} and k in K and t is j^4 or its inverse,";
print "so that b^mu*k*t*k^-1*b^(-mu)*j^(-4) is in Pi.";
for tidx in [1 .. #torsionreplist] do
 if (tidx eq 5) then // We want to treat the case j^4 separately.
  for mu in [0,1,-1] do
   testgp:=sub< G | a1,a2,a3,b^mu*torsionreplist[tidx]*b^(-mu)*j^(-4)>;
   idx:=Index(G,testgp);
   if (idx eq 864) then print "b^",mu,"*",torsionrepwordlist[tidx],"^-1*b^",-mu,"*j^-4 is in Pi"; end if;
   testgp:=sub< G | a1,a2,a3,b^mu*torsionreplist[tidx]^-1*b^(-mu)*j^(-4)>;
   idx:=Index(G,testgp);
   if (idx eq 864) then print "b^",mu,"*",torsionrepwordlist[tidx],"^(-1)*b^",-mu,"*j^-4 is in Pi"; end if;
  end for;
 end if;
end for;

// Output:
// b^0*(j*j*j*j)^-1*b^0*j^-4 is in Pi
// b^1*(j*j*j*j)^-1*b^-1*j^-4 is in Pi
// b^-1*(j*j*j*j)^-1*b^1*j^-4 is in Pi

// End of calculations for Proposition 11.
// ***************************************